# Regular expressions quick intro:
# - <a> is the non-terminal a
# - "abc" means "the literal string abc"
# - <a> = b means "a is defined as b"
# - between any two tokens spaces can be inserted
# - ( a ) means a
# - a b means "a and then b (with optional spaces
#   inbetween)"
# - a | b means "a or b"
# - a* means "a zero or more times"
# - a+ means "a one or more times"
# - a? means "a zero or one time"
# - [abc] means "any from characters a, b or c"
# - [a-b] means "any character in the range a to b"


######### Problem definition specification #########
# Additional context-dependent or semantic
# assumptions:
# - each of <ptype>, <vtype> and <order> must occur
#   at least once
# - all <ptype>-s occur before any <vtype>
# - all <vtype>-s occur before any <order>
# - distance between two customers is calculated as
#   planar Euclidean distance,
#   i.e. d^2 = (p1.x-p2.x)^2 + (p1.y-p2.y)^2
# - all data types (decimals, integers) will be
#   small enough to fit into standard Java types

<problem-definition> = "problem" <ws> <problem-name>
    <eol> (<empty> | <ptype> | <vtype> | <order>)*
<problem-name> = <name>

# Product type definition
# e.g. ptype karton1
<ptype> = "ptype" <ws> <ptype-name> <eol>
<ptype-name> = <name>

# Vehicle type definition
# e.g. vtype tir 1000 4.50 60.0 (europaleta:33,
#      karton1:1000) (16.47, 20.3)
<vtype> = "vtype" <ws> <vtype-name> <ws>
    <vtype-usage-cost> <ws> <vtype-kilometer-cost>
    <ws> <vtype-speed> <ws> <vtype-caps> <ws>
    <vtype-base> <eol>
<vtype-name> = <name>
<vtype-usage-cost> = <decimal>
<vtype-kilometer-cost> = <decimal>
<vtype-speed> = <decimal>
<vtype-caps> = "(" <vtype-cap> ("," <vtype-cap>)* ")"
<vtype-cap> = <ptype-name> ":" <integer>
<vtype-base> = <point>

# Order definition
# e.g. order europaleta:20 (16.47, 20.3) (18.10, 19)
#      08:00-23:59 12:00-17:00 5
<order> = "order" <ws> <order-product> <ws>
    <order-from> <ws> <order-to> <ws>
    <order-from-tw> <ws> <order-to-tw> <ws>
    <order-visits> <eol>
<order-product> = <ptype-name> ":" <integer>
<order-from> = <point>
<order-to> = <point>
<order-from-tw> = <time-window>
<order-to-tw> = <time-window>
<order-visits> = [1-7]


######### Result specification #########
# Additional context-dependent or semantic
# assumptions:
# - there must be exactly 7 different days
# - the result must fulfill all constraints specified
#   in problem description
# - problem specification will not allow for
#   ambiguous result file (e.g. each point will
#   appear only once in only one order)
# - all data types (decimals, integers) will be small
#   enough to fit into standard Java types

<result-definition> = "result" <ws> <problem-name>
    <eol> <days>
<days> = (<day> (<route> | <empty>)*)+
<day> = "day" <ws> <day-number> <eol>
<day-number> = [1-7]
<route> = <vtype-name> <ws> <vtype-base> <ws>
    <point>+ <ws> <vtype-base> <eol>

######### Common defintions #########
<empty> = <ws>? <eol>

<name> = [a-zA-Z_0-9.\-]+
<integer> = [0-9]+
<decimal> = <integer> ( "." [0-9]+)?
<point> = "(" <decimal> "," <decimal> ")"

<time-window> = <hour-minute> "-" <hour-minute>
<hour-minute> = <hour> ":" <minute>
<hour> = ([0-1] [0-9]) | ("2" [0-3])
<minute> = [0-5] [0-9]

<ws> = " "+
<eol> = "\n" | "\r\n"